ESP32 CAM安装配置 第一部份：通过Arduino和Camerawebserver设置ESP32 Cam

下载开发工具：Software | Arduino

下载usb转com驱动程序：

驱动程序 - 南京沁恒微电子股份有限公司

下载Raspberry Pi image工具：Raspberry Pi OS – Raspberry Pi

购买ESP32 CAM和烧录底坐：https://m.tb.cn/h.5KxUeY5dNjn9Z6Z?tk=irVsW7tTRxp CZ3457

注意：要确认下是不是AI Thinker Esp32的板子(其它主板也可以，但本人没有测试过)

准备好一条microusb的数据线和5V/2A的电源

准备工作就绪

第一部份：通过Arduino和Camerawebserver设置ESP32 Cam

  1. 安装开发程序Arduino,我用的是最新版2.2.1
  2. 安装完成配置首选项，填加ESP32的开发管理器，打开文件---首选项

将以下两个网址加上，一行一个，确定退出

https://dl.espressif.com/dl/package_esp32_index.json

https://espressif.github.io/arduino-esp32/package_esp32_index.json

   

在 Arduino IDE 中，找到 工具>开发板>开发板开发板管理，搜索 ESP32 或者直接选择 ESP32WroverModule

  1. 选择开发板，Ai Thinker ESP32-CAM,并将底坐和主板，microusb连接到电脑，注意Com口，如果没有显示COM口，可能是你没有安装驱动程序，可打开工具---串口监视器来看是否连接上

  1. 选择 文件>示例>ESP32>Camera>CameraWebServer ,进入示例代码界面。

  1. 修改程序代码,修改红色字体部份

#include "esp_camera.h"

#include <WiFi.h>

//

// WARNING!!! PSRAM IC required for UXGA resolution and high JPEG quality

//            Ensure ESP32 Wrover Module or other board with PSRAM is selected

//            Partial images will be transmitted if image exceeds buffer size

//

//            You must select partition scheme from the board menu that has at least 3MB APP space.

//            Face Recognition is DISABLED for ESP32 and ESP32-S2, because it takes up from 15

//            seconds to process single frame. Face Detection is ENABLED if PSRAM is enabled as well

// ===================

// Select camera model

// ===================

//#define CAMERA_MODEL_WROVER_KIT // Has PSRAM

//#define CAMERA_MODEL_ESP_EYE // Has PSRAM

//#define CAMERA_MODEL_ESP32S3_EYE // Has PSRAM

//#define CAMERA_MODEL_M5STACK_PSRAM // Has PSRAM

//#define CAMERA_MODEL_M5STACK_V2_PSRAM // M5Camera version B Has PSRAM

//#define CAMERA_MODEL_M5STACK_WIDE // Has PSRAM

//#define CAMERA_MODEL_M5STACK_ESP32CAM // No PSRAM

//#define CAMERA_MODEL_M5STACK_UNITCAM // No PSRAM

 #define CAMERA_MODEL_AI_THINKER // Has PSRAM

//#define CAMERA_MODEL_TTGO_T_JOURNAL // No PSRAM

//#define CAMERA_MODEL_XIAO_ESP32S3 // Has PSRAM

// ** Espressif Internal Boards **

//#define CAMERA_MODEL_ESP32_CAM_BOARD

//#define CAMERA_MODEL_ESP32S2_CAM_BOARD

//#define CAMERA_MODEL_ESP32S3_CAM_LCD

//#define CAMERA_MODEL_DFRobot_FireBeetle2_ESP32S3 // Has PSRAM

//#define CAMERA_MODEL_DFRobot_Romeo_ESP32S3 // Has PSRAM

#include "camera_pins.h"

// ===========================

// Enter your WiFi credentials

// ===========================

//修改成自己的wifi ssid和密码，注意这里的wifi,要启用2.4G，有些主板不支持5G信道

const char* ssid = "Guest";

const char* password = "2021###";

void startCameraServer();

void setupLedFlash(int pin);

void setup() {

  Serial.begin(115200);

  Serial.setDebugOutput(true);

  Serial.println();

  camera_config_t config;

  config.ledc_channel = LEDC_CHANNEL_0;

  config.ledc_timer = LEDC_TIMER_0;

  config.pin_d0 = Y2_GPIO_NUM;

  config.pin_d1 = Y3_GPIO_NUM;

  config.pin_d2 = Y4_GPIO_NUM;

  config.pin_d3 = Y5_GPIO_NUM;

  config.pin_d4 = Y6_GPIO_NUM;

  config.pin_d5 = Y7_GPIO_NUM;

  config.pin_d6 = Y8_GPIO_NUM;

  config.pin_d7 = Y9_GPIO_NUM;

  config.pin_xclk = XCLK_GPIO_NUM;

  config.pin_pclk = PCLK_GPIO_NUM;

  config.pin_vsync = VSYNC_GPIO_NUM;

  config.pin_href = HREF_GPIO_NUM;

  config.pin_sccb_sda = SIOD_GPIO_NUM;

  config.pin_sccb_scl = SIOC_GPIO_NUM;

  config.pin_pwdn = PWDN_GPIO_NUM;

  config.pin_reset = RESET_GPIO_NUM;

  config.xclk_freq_hz = 20000000;

  config.frame_size = FRAMESIZE_UXGA;

  config.pixel_format = PIXFORMAT_JPEG; // for streaming

  //config.pixel_format = PIXFORMAT_RGB565; // for face detection/recognition

  config.grab_mode = CAMERA_GRAB_WHEN_EMPTY;

  config.fb_location = CAMERA_FB_IN_PSRAM;

  config.jpeg_quality = 12;

  config.fb_count = 1;

  // if PSRAM IC present, init with UXGA resolution and higher JPEG quality

  //                      for larger pre-allocated frame buffer.

  if(config.pixel_format == PIXFORMAT_JPEG){

    if(psramFound()){

      config.jpeg_quality = 10;

      config.fb_count = 2;

      config.grab_mode = CAMERA_GRAB_LATEST;

    } else {

      // Limit the frame size when PSRAM is not available

      config.frame_size = FRAMESIZE_SVGA;

      config.fb_location = CAMERA_FB_IN_DRAM;

    }

  } else {

    // Best option for face detection/recognition

    config.frame_size = FRAMESIZE_240X240;

#if CONFIG_IDF_TARGET_ESP32S3

    config.fb_count = 2;

#endif

  }

#if defined(CAMERA_MODEL_ESP_EYE)

  pinMode(13, INPUT_PULLUP);

  pinMode(14, INPUT_PULLUP);

#endif

  // camera init

  esp_err_t err = esp_camera_init(&config);

  if (err != ESP_OK) {

    Serial.printf("Camera init failed with error 0x%x", err);

    return;

  }

  sensor_t * s = esp_camera_sensor_get();

  // initial sensors are flipped vertically and colors are a bit saturated

  //修改此处摄像头型号，可选用OV5640和OV2640

  if (s->id.PID == OV2640_PID) {

    s->set_vflip(s, 1); // flip it back

    s->set_brightness(s, 1); // up the brightness just a bit

    s->set_saturation(s, -2); // lower the saturation

  }

  // drop down frame size for higher initial frame rate

  if(config.pixel_format == PIXFORMAT_JPEG){

    s->set_framesize(s, FRAMESIZE_QVGA);

  }

#if defined(CAMERA_MODEL_M5STACK_WIDE) || defined(CAMERA_MODEL_M5STACK_ESP32CAM)

  s->set_vflip(s, 1);

  s->set_hmirror(s, 1);

#endif

#if defined(CAMERA_MODEL_ESP32S3_EYE)

  s->set_vflip(s, 1);

#endif

// Setup LED FLash if LED pin is defined in camera_pins.h

#if defined(LED_GPIO_NUM)

  setupLedFlash(LED_GPIO_NUM);

#endif

  WiFi.begin(ssid, password);

  WiFi.setSleep(false);

  while (WiFi.status() != WL_CONNECTED) {

    delay(500);

    Serial.print(".");

  }

  Serial.println("");

  Serial.println("WiFi connected");

  startCameraServer();

  Serial.print("Camera Ready! Use 'http://");

  Serial.print(WiFi.localIP());

  Serial.println("' to connect");

}

void loop() {

  // Do nothing. Everything is done in another task by the web server

  delay(10000);

}

  1. 修改完成后，点Arduino的编译，上传，将程序烧录到ESP32-CAM，出现红色标注内容说明烧录成功

  1. 打开串口连接器，进行查看，此时可以看到Wifi已经连接，并有IP地址

  1. 将你的电脑wifi与ESP32 CAM的网络设置到同一SSID或VLAN,确保网络能通讯，打开浏览器，输入上面的联接，你就可以连接到摄像头。记住以下三个地址

http://ip

http://ip:81/stream：查看视频流

http://ip/capture:查看静态页面

  1. 点Get Still和Start Stream,这时你就可以看到有摄像头和视频流，如果要启用人脸识别，需要按红色框设置

  1. 到此，可以通过Web来设置摄像头，另外在设置过程中，可能会有图像不清楚，翻转等问题，可通过设置参数，更换电源尝试，如果摄像头翻转，调整V-Flip参数